Для решения одномерных задач о столкновениях применялись законы сохранения линейного импульса и кинетической энергии. Однако в многомерных задачах число степеней свободы превышает число ограничений, даваемых законами сохранения.

Пусть частица массой m, двигаясь по оси х, налетает со скоростью v0 на частицу массы M, которая вначале покоится. Частицы взаимодействуют центральным образом. Попытка решения на основе законов сохранения означает неучет деталей столкновения. Полное динамическое решение уравнения Ньютона (в форме хоть Лагранжа, хоть Гамильтона) учитывает закон силы и законы сохранения. Примером была задача об артиллерийском ядре.

Ограничения:

1. Сохранение углового момента при центральном движении объектов означает движение в плоскости, что для векторов положения масс уменьшает число степеней свободы до двух. Число степеней свободы системы уменьшается с шести до четырех.
2. Сохранение энергии дает одно скалярное ограничение, т. е. остаются три степени свободы.
3. Сохранение линейного импульса в плоскости рассеяния дает два ограничения.

Тогда получается, что на основе только законов сохранения задачу нельзя полностью обусловить. Это доказывается ниже. Вначале – в общем виде, затем – для случая рассеяния фотонов на электронах атома, результатом чего является передача энергии электрону, т. е. для задачи о комптоновском рассеянии.

Запишем уравнения для ограничений 2 и 3, т. е. начинаем в плоскости рассеяния (полученной из закона сохранения углового момента). Полагаем удар полностью упругим, хотя несложно ввести в энергетический баланс долю энергии, которая передается массе М.

• En:=m/2*v0^2=m/2*v^2+M/2*V^2;

Чтобы обозначить компоненты импульса после столкновения, введем два угла относительно оси х: θ для рассеиваемой частицы m и φ для частицы М.

• Momx:=m*v0=m*v*cos(theta)+M*V*cos(phi);
• Momy:=0=m*v*sin(theta)+M*V*sin(phi);

Что нам нужно?

Массы частиц и начальная скорость v0 известны. Неизвестны четыре величины: v, V, θ, φ. Как использовать три условия (ограничения), чтобы получить максимум сведений для задачи?

Прежде чем перейти к общей ситуации, рассмотрим случай одинаковых масс.

• En1:=subs(M=m,En);
• Momx1:=subs(M=m,Momx);
• Momy1:=subs(M=m,Momy);

При трех заданных уравнениях мы можем получить решение для трех переменных:

• sol:=solve({En1,Momx1,Momy1},{v,V,theta});

Команда solve в Maple находит набор четырех приемлемых решений. Посмотрим, что они подразумевают:

• Набор 1 описывает ситуацию до столкновения.
• Набор 2 описывает зеркальный образ набора 1.
• Наборы 3 и 4 присваивают соответствующую скорость массе М.

Если считать, что θ и φ – в диапазонах 0..π/2 и –π/2..0 соответственно, т. е. обе массы движутся вправо, при том что m отклоняется в положительном направлении y, а M движется вниз, ясно, что набор 4 интересен. Скорость v должна быть положительна.

Получается интересный вывод.

Очевидно, что угол рассеяния φ произволен (в диапазоне –π/2..0), а угол рассеяния θ задается через φ. Получается хорошо известный результат для упругого рассеяния одинаковых масс, а именно: два объекта рассеиваются под прямым углом относительно друг друга.

Более того, при заданном угле φ распределение энергий между падающей и отскочившей частицами фиксировано. Для каждого угла рассеяния φ (или θ) кинетическая энергия обоих объектов фиксирована.

• assign(sol[4]);
• print(v,V);
• KEm:=m*v^2/2;
• KEM:=m*V^2/2;
• m:=1;
  v0:=10;
• plot([KEm,KEM],phi=-Pi/2..0,color=[blue,green],axes=BOXED);

Очевидно, сумма кинетических энергий двух масс (случай M = m) не зависит от φ и равна m*v0²/2.

Предельные случаи соответствуют следующим ситуациям:

• φ = 0, θ = π/2: налетающая масса остается неподвижной (KEm = 0), а угол θ не существенен. Ударяемая частица (M) движется в направлении вперед с максимальной кинетической энергией. Это соответствует лобовому удару, который можно рассчитать в одномерной геометрии;
• φ = –π/2, θ = 0: налетающая масса не передает энергию ударяемой массе (KEM = 0), φ не существенен. Это соответствует скользящему столкновению, когда частицы очень слабо взаимодействуют. Интереснее ситуация до достижения предельного случая (малоугловое рассеяние), когда ударяемая частица отскакивает под углом почти 90° и берет только небольшую часть кинетической энергии;
• φ = –π/4, θ = π/4: равное распределение энергии после столкновения.

Теперь можно рассмотреть общий случай:

• restart;
• En:=m/2*v0^2=m/2*v^2+M/2*V^2;
• Momx:=m*v0=m*v*cos(theta)+M*V*cos(phi);
• Momy:=0=m*v*sin(theta)+M*V*sin(phi);
• sol:=solve({En,Momx,Momy},{v,V,theta});

Теперь вспомним, что обычно начальное условие и его зеркальный вариант являются решениями системы уравнений. Проанализируем интересное решение:

• assign(sol[3]);
• v;
• V;
• theta;

Мы учитываем, что соотношение между θ и φ сложнее. Сначала проанализируем более простую часть. Кинетическая энергия ударяемой частицы – все еще функция угла рассеяния. Заметим, что функция arctan может иметь два аргумента:

• KEM:=M/2*V^2;

При фиксированном угле φ можно использовать зависимость этой кинетической энергии от отношения масс:

• phi:=-Pi/4; v0:=10; m:=1; M:=r*m;
• KEM;
• KEtot:=m/2*v0^2;

Сделаем полулогарифмический график и диапазон масс (по абсциссе) от 0.001 до 1000.

• plot(subs(r=10^s,KEM)/KEtot,s=-3..3);

Из графика получим, что для передачи энергии случай одинаковых масс наиболее эффективен. Если отношение масс r = M/m либо мало, либо велико, то при φ = –45° часть переданной массе M кинетической энергии становится очень малой.

Остальные определенные нами переменные выглядят несколько неуклюже. Квадратный корень не вычисляется во избежание случайностей. Они несколько упрощаются при задании m и v0.

• v;
• simplify(v);
• evalf(subs(r=1,%));

Maple, к сожалению, дает только один из корней, но с отрицательным знаком…

Считая, что простой квадратный корень задан, преобразуем RootOf в радикал:

• ### ПРЕДУПРЕЖДЕНИЕ: переменная `I` перестала быть типом `radical`
  v:=convert(v,radical);

Чтобы показать ту часть кинетической энергии, что остается у массы m после столкновения при особом случае φ = –45° как функции отношения масс, рассчитаем:

• plot(subs(r=10^s,v)^2/v0^2,s=-3..3);

Очевидно, это дополнение к предыдущему графику. Рассмотрим соответствующие углы рассеяния для частицы с массой m:

• ### ПРЕДУПРЕЖДЕНИЕ: переменная `I` перестала быть типом `radical`
  
• theta:=convert(theta,radical);
• plot(subs(r=10^s,theta),s=-3..3);

Случай равных масс (s = 0, r = 1) дает ожидаемое значение θ = 45°.

В пределе, когда r = M/m → 0 (s велико и отрицательно, т. е. падающая частица массивна в сравнении с частицей-мишенью), угол рассеяния для падающей частицы стремится к нулю (учтем, что φ = –π/4).

В пределе, когда r = M/m → ∞ (s велико и положительно, т. е. по сравнению с частицей-мишенью падающая частица – легкая), угол рассеяния для падающей частицы стремится к π. Это означает, что от тяжелого объекта отражение происходит при φ = –45°. Сюда входит предельный случай лобового столкновения с простым отражением, как показывает предыдущий график, в пределе большого r на тяжелую массу М энергия не передается (ее угол выхода φ становится неопределенным).

Другой интересный случай – когда энергии ударяющей частицы фиксирована и необходимо изучить допустимый диапазон углов рассеяния φ.

Теперь все готово, чтобы обсудить комптоновское рассеяние.

При этом придется учесть, что фотоны не являются массивными частицами. Эффект Комптона возникает при прохождении света (в частности – рентгеновских лучей) через вещество, причем в результате энергия фотонов уменьшается (т. е. длина волны возрастает). Изменение длины волны зависит от угла рассеяния фотонов. Объяснение эффекта основано на том, что фотоны рассматриваются как частицы. Задача похожа на предыдущую, к которой добавляется выражение для энергии и импульса фотонов.

Импульс фотонов до столкновения обозначим p0 и запишем его через постоянную Планка h, частоту ν0 и скорость света с:

• restart;
• p0:=h*nu0/c;

Закон сохранения импульса:

• Momx:=p0=h*nu/c*cos(theta)+P*cos(phi);
• Momy:=0=h*nu/c*sin(theta)+P*sin(phi);

Для записи закона сохранения энергии нужно учесть релятивистское приближение для энергии – импульса (при большой энергии фотонов на электрон можно передать большую часть кинетической энергии).

Кинетическая энергия до столкновения – это энергия покоя электрона (предполагается, что электрон – свободный, с массой покоя M) плюс энергия фотона:

• En:=h*nu0+M*c^2=h*nu+Eel;

Прежде чем решать, нужно выразить энергию электрона после соударения через массу покоя М и конечный импульс Р:

• En1:=subs(Eel=sqrt(M^2*c^4+P^2*c^2),En);
• sol:=solve({Momx,Momy,En1},{nu,P,phi});

Вещество на самом деле сложнее…

Можем ограничить угол эмиссии электронов φ, возведя в квадрат уравнения сохранения импульса:

• ex1:=solve(Momx,P*cos(phi));
• ex2:=solve(Momy,P*sin(phi));
• eq1:=ex1^2+ex2^2=P^2;
• eq1:=simplify(eq1);
• sol:=solve({En1,eq1},{P,nu});
• assign(sol);
• nu;

Если мы только интересуемся сдвигом длины волны как функции угла рассеяния фотона, то надо делать так: сначала используем соотношение с = λν, чтобы получить выражение для длины волны рассеянного фотона:

• eq2:=nu=c/lambda;

Теперь подставим частоту ν0.

• eq3:=subs(nu0=c/lambda0,eq2);
• eq3:=simplify(eq3);

Сдвиг длины волны Δ получится как разность исходной длины волны λ0 и λ. Последняя получится из eq3:

• Delta:=simplify(solve(eq3,lambda)-lambda0);

Сдвиг длины волны Δ не зависит от исходной длины волны λ0 и задается как произведение длины волны электрона, а именно комптоновской длины волны электрона h/(M*c). В этих единицах сдвиг длины волны как функция угла рассеяния фотона задается графиком:

• plot(1-cos(theta),theta=0..Pi);

Сдвиг длины волны максимален в обратном направлении. Максимум неупругости соответствует двойной комптоновской длине волны частицы (в нашем случае это электрон), на которую налетает фотон.

В прямом направлении фотоны пролетают без передачи энергии.

Оценим размеры шкалы комптоновских длин волн для электрона:

• lambda[C]:=h/(M*c);
• h:=6.63*10^(-34)*_N*_m*_s; #Planck's constant in SI units
• c:=3.*10^8*_m/_s; # speed of light in SI units
• M:=9.11*10^(-31)*_kg; # electron mass in SI units
• lambda[C];
• subs(_N=_kg*_m/_s^2,%);

Максимальный сдвиг длины волны для свободного электрона равен приблизительно 5 · 10^–12 м, т. е. 0.05 ангстрема. Для сравнения: жесткое рентгеновское излучение в сотни тысяч раз короче видимого света, и для него сдвиг длины волны достигает процента.

Получается, что мягкие фотоны рассеиваются на электронах назад без существенной потери энергии, а жесткие фотоны передают заметную часть энергии. Но вещество намного сложнее, потому что мягкие фотоны могут возбуждать электронные переходы между связанными состояниями.